<%
'##############################################################################
'#
'# 変数宣言
'#
'##############################################################################
Dim errFlg
Dim objFSO 'ファイルシステムオブジェクト
Dim strPath 'ファイル保存先パス Application("WhatsNewFilePath")環境による
Dim strFileName 'ファイルの名前
Dim objFile 'ファイルのオブジェクト
Dim strLine '１行分データ
Dim arrLine '１行分配列データ
Dim intCntY '縦行数
Dim arrDate(5) '日付配列
Dim arrInfo(5) '新着情報配列
'##############################################################################
'#
'# 代入
'#
'##############################################################################
errFlg = 0
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
strPath = Application("WhatsNewFilePath")
strFileName = "whatsnew.dat"
intCntY = 0
For intCntY = 1 To 4
arrDate(intCntY) = "" '日付
arrInfo(intCntY) = "" '内容
Next
'##############################################################################
'#
'# チェック（エラーの場合は新着情報欄に表示）
'#
'##############################################################################
'フォルダの確認
If errFlg = 0 Then
'フォルダの有無
If objFSO.FolderExists(strPath) = False Then
'フォルダがありません。
arrInfo(1) = "新着情報データの保存先フォルダがありません。"
errFlg = 1
End If
End If
'ファイルの有無
If errFlg = 0 Then
If objFSO.FileExists(strPath & "\" & strFileName) = False Then
'ファイルがありません。
arrInfo(1) = "新着情報データファイルがありません。"
errFlg = 1
End If
End If
'##############################################################################
'#
'# 表示用に代入
'#
'##############################################################################
If errFlg = 0 Then
intCntY = 0
'ファイルを開く
Set objFile = objFSO.OpenTextFile(strPath & "\" & strFileName,1)
'データが終わるまで
Do While objFile.AtEndOfStream <> True
strLine = objFile.ReadLine '１行読み込み
arrLine = Split(strLine,",") '配列化
'配列の場合
If IsArray(arrLine) Then
'データ項目が2個（日付と内容）
If UBound(arrLine) = 1 Then
intCntY = intCntY + 1
arrDate(intCntY) = arrLine(0) '日付
arrInfo(intCntY) = arrLine(1) '内容
End If
End If
If intCntY = 4 Then
Exit Do
End If
Loop
objFile.Close
End If
Set objFile = Nothing
Set objFSO = Nothing
'##############################################################################
%>
| <%=arrDate(1)%> |
<%=arrInfo(1)%> |
| <%=arrDate(2)%> |
<%=arrInfo(2)%> |
| <%=arrDate(3)%> |
<%=arrInfo(3)%> |
| <%=arrDate(4)%> |
<%=arrInfo(4)%> |
〒470-1219
愛知県豊田市畝部西町昆布池40-1
【営業時間】AM 8:30〜PM 7:00
【休業日】日曜・祭日
